Вольфрам

[Gruber]

Здравствуйте! Подскажите, пожалуйста, что не так. Вольфрам верно считает диффур, но график траектории строить отказывается:

g = 9.8;
a = Pi/4;
v = 10;
m = v*Cos[a];
Plot[DSolve[{x''[t] == 0, x'[0] == m, x[0] == 0}, x[t], t], {t, 0, 1}]

[Ms-dos4]

Ещё бы. Сделайте напимер так

g = 9.8;
a = Pi/4;
v = 10;
m = v*Cos[a];
DSolve[{x''[t] == 0, x'[0] == m, x[0] == 0}, x[t], t]
Plot[Evaluate[x[t] /. %], {t, 0, 1}]

[Nemiroff]

(Оффтоп)

Gruber в сообщении #924345 писал(а):

Вольфрам верно считает диффур, но график траектории строить отказывается:

Стивен?

[Gruber]

Ms-dos4 , спасибо! А не могли бы Вы,пожалуйста, ещё объяснить, почему в этом случае работает и что делает конструкция Evaluate[x[t]/.%] ?





Nemiroff, если бы Стивен бы всё посчитал, то и график бы построил

[Mysterious Light]

Удержание.
Некоторые функции, в т.ч. Plot, удерживают от преждевременной редукции свои аргументы (аттрибут со словом Hold в списке аттрибутов Attributes[Plot]). Это нужно для того, чтобы не вычислять то, что не нужно вычислять до вызова этой функции. В частности, в выражении Plot[expr, range] expr должно вычислять несколько раз во время построения графика, а не до начала построения.

Для того, чтобы это обойти, можно действовать тремя путями:
1. Использовать специальную функцию Evaluate, которая принудительно вычисляет аргумент:

Plot[Evaluate[x[t] /. DSolve[{x''[t] == 0, x'[0] == m, x[0] == 0}, x[t], t]], {t, 0, 1}]

2. Разделить на несколько ячеек и вычислять последовательно:

x[t] /. DSolve[{x''[t] == 0, x'[0] == m, x[0] == 0}, x[t], t]
Plot[%, {t, 0, 1}]

3. Использовать With:

With[{func = x[t] /. DSolve[{x''[t] == 0, x'[0] == m, x[0] == 0}, x[t], t]},
  Plot[func, {t, 0, 1}]]

Формат выражений
DSolve возвращает список (списков) правил замены Rule вида x[t] -> ... (стрелочка и Rule суть синонимы).
Plot же ожидает числовое выражение. Поэтому нужно приводить форматы, используя конструкцию x[t] /. DSolve[...].
Гипотетички, можно ещё Last /@ DSolve[...], но лучше с этим не играться.

[Aritaborian]

На случай, если ТС не знает и этого, скажу ещё, что % означает последний вычисленный результат.
Пример.

a = 1;
b = % + 2

b будет равно трём.

[Gruber]

Спасибо всем огромное! Разобрался